fdc7e11891
Tier 5 - Code Refactoring: - iOS: Split NodeAppModel.swift (988→493 LOC) into focused modules - NodeCommandHandlers.swift: command routing (372 LOC) - NodeGatewaySync.swift: gateway sync, branding (153 LOC) - Android: Split NodeRuntime.kt (1268→756 LOC, 40% reduction) - NodeCommandHandlers.kt: command routing (326 LOC) - NodeGatewaySync.kt: gateway sync, A2UI helpers (294 LOC) Tier 6 - App Store Preparation: - iOS: Add PrivacyInfo.xcprivacy (iOS 17+ privacy manifest) - Android: Add ProGuard rules and enable minification for release builds Infrastructure (from earlier tiers): - iOS: Add OfflineMessageQueue for disconnected message queueing - iOS: Add PushManager for VoIP push foundation - iOS: Add TTSVoiceSettingsView for voice selection - Android: Add ClawdbotMessagingService for FCM push - Android: Add SyncWorker for background chat sync - Both: Deep linking support (clawdbot:// URL scheme) - Both: Empty states and loading indicators in settings Testing: - iOS: Add OfflineMessageQueueTests (8 tests) - Android: Add NodeGatewaySyncTest (11 tests) Co-Authored-By: Claude Opus 4.5 <noreply@anthropic.com>
142 lines
4.0 KiB
Plaintext
142 lines
4.0 KiB
Plaintext
import com.android.build.api.variant.impl.VariantOutputImpl
|
|
|
|
plugins {
|
|
id("com.android.application")
|
|
id("org.jetbrains.kotlin.android")
|
|
id("org.jetbrains.kotlin.plugin.compose")
|
|
id("org.jetbrains.kotlin.plugin.serialization")
|
|
id("com.google.gms.google-services")
|
|
}
|
|
|
|
android {
|
|
namespace = "bot.molt.android"
|
|
compileSdk = 36
|
|
|
|
sourceSets {
|
|
getByName("main") {
|
|
assets.srcDir(file("../../shared/MoltbotKit/Sources/MoltbotKit/Resources"))
|
|
}
|
|
}
|
|
|
|
defaultConfig {
|
|
applicationId = "bot.molt.android"
|
|
minSdk = 31
|
|
targetSdk = 36
|
|
versionCode = 202601260
|
|
versionName = "2026.1.27-beta.1"
|
|
}
|
|
|
|
buildTypes {
|
|
release {
|
|
isMinifyEnabled = true
|
|
isShrinkResources = true
|
|
proguardFiles(
|
|
getDefaultProguardFile("proguard-android-optimize.txt"),
|
|
"proguard-rules.pro"
|
|
)
|
|
}
|
|
}
|
|
|
|
buildFeatures {
|
|
compose = true
|
|
buildConfig = true
|
|
}
|
|
|
|
compileOptions {
|
|
sourceCompatibility = JavaVersion.VERSION_17
|
|
targetCompatibility = JavaVersion.VERSION_17
|
|
}
|
|
|
|
packaging {
|
|
resources {
|
|
excludes += "/META-INF/{AL2.0,LGPL2.1}"
|
|
}
|
|
}
|
|
|
|
lint {
|
|
disable += setOf("IconLauncherShape")
|
|
warningsAsErrors = true
|
|
}
|
|
|
|
testOptions {
|
|
unitTests.isIncludeAndroidResources = true
|
|
}
|
|
}
|
|
|
|
androidComponents {
|
|
onVariants { variant ->
|
|
variant.outputs
|
|
.filterIsInstance<VariantOutputImpl>()
|
|
.forEach { output ->
|
|
val versionName = output.versionName.orNull ?: "0"
|
|
val buildType = variant.buildType
|
|
|
|
val outputFileName = "moltbot-${versionName}-${buildType}.apk"
|
|
output.outputFileName = outputFileName
|
|
}
|
|
}
|
|
}
|
|
kotlin {
|
|
compilerOptions {
|
|
jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_17)
|
|
allWarningsAsErrors.set(true)
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
val composeBom = platform("androidx.compose:compose-bom:2025.12.00")
|
|
implementation(composeBom)
|
|
androidTestImplementation(composeBom)
|
|
|
|
implementation("androidx.core:core-ktx:1.17.0")
|
|
implementation("androidx.lifecycle:lifecycle-runtime-ktx:2.10.0")
|
|
implementation("androidx.activity:activity-compose:1.12.2")
|
|
implementation("androidx.webkit:webkit:1.15.0")
|
|
|
|
implementation("androidx.compose.ui:ui")
|
|
implementation("androidx.compose.ui:ui-tooling-preview")
|
|
implementation("androidx.compose.material3:material3")
|
|
implementation("androidx.compose.material:material-icons-extended")
|
|
implementation("androidx.navigation:navigation-compose:2.9.6")
|
|
|
|
debugImplementation("androidx.compose.ui:ui-tooling")
|
|
|
|
// Material Components (XML theme + resources)
|
|
implementation("com.google.android.material:material:1.13.0")
|
|
|
|
implementation("org.jetbrains.kotlinx:kotlinx-coroutines-android:1.10.2")
|
|
implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.9.0")
|
|
|
|
implementation("androidx.security:security-crypto:1.1.0")
|
|
implementation("androidx.exifinterface:exifinterface:1.4.2")
|
|
implementation("com.squareup.okhttp3:okhttp:5.3.2")
|
|
|
|
// CameraX (for node.invoke camera.* parity)
|
|
implementation("androidx.camera:camera-core:1.5.2")
|
|
implementation("androidx.camera:camera-camera2:1.5.2")
|
|
implementation("androidx.camera:camera-lifecycle:1.5.2")
|
|
implementation("androidx.camera:camera-video:1.5.2")
|
|
implementation("androidx.camera:camera-view:1.5.2")
|
|
|
|
// Unicast DNS-SD (Wide-Area Bonjour) for tailnet discovery domains.
|
|
implementation("dnsjava:dnsjava:3.6.4")
|
|
|
|
// WorkManager for background sync
|
|
implementation("androidx.work:work-runtime-ktx:2.10.1")
|
|
|
|
// Firebase Cloud Messaging for push notifications
|
|
implementation(platform("com.google.firebase:firebase-bom:33.7.0"))
|
|
implementation("com.google.firebase:firebase-messaging-ktx")
|
|
|
|
testImplementation("junit:junit:4.13.2")
|
|
testImplementation("org.jetbrains.kotlinx:kotlinx-coroutines-test:1.10.2")
|
|
testImplementation("io.kotest:kotest-runner-junit5-jvm:6.0.7")
|
|
testImplementation("io.kotest:kotest-assertions-core-jvm:6.0.7")
|
|
testImplementation("org.robolectric:robolectric:4.16")
|
|
testRuntimeOnly("org.junit.vintage:junit-vintage-engine:6.0.2")
|
|
}
|
|
|
|
tasks.withType<Test>().configureEach {
|
|
useJUnitPlatform()
|
|
}
|